openMSX "sprite rivelator"

When I want to check for such tricks, I usually just disable de sprites on the openMSX-Debugger.

Works like a charm on FireHawk, i.e.

Emh manuel, i'm not sure about your question can you elaborate this "if you tell me where all this sprite data is available".
sprite data are the SAT contents. the real vdp itself know through its registers where sat data is placed. in "msx basic pseudo code" is some thing like this:

BASEADDR=vdp(5)*256*vdp(12)*128 : REM not sure about this, but should be the base SAT address....
FOR T=0 To 31
y=vpeek(BASEADDR+T*4)
x=vpeek(BASEADDR+1+T*4)
line (x,y)-step(15,15),15,b: REM i assume 16x16 pixel wide sprites.... should be adapted to vdp sprite size and magnification settings
next T

this should draw squared box but on the openMSX overlayed - emulated msx screen not on the msx vram itself of course. It's only to show what i mean. This should also work at every frame rendering in openMSX window...

OK, I made a prototype, got the addressing from the Wiki, but the addressing isn't (apparently) fully clear to me for MSX2 modes, as it's not working there. This is what I got so far:

namespace eval sprite_locator {

variable sprite_locator_enabled false
variable sprite_locator_after_id 0

set_help_text toggle_sprite_locator \
"Shows the locations of all 32 sprites according to the current VDP state."

proc toggle_sprite_locator {} {
	variable sprite_locator_enabled
	variable sprite_locator_after_id

	if {$sprite_locator_enabled} {
		set sprite_locator_enabled false
		osd destroy sprite_locator
		catch { after cancel $sprite_locator_after_id }
		return "Sprite locator disabled"
	} else {
		set sprite_locator_enabled true
		osd_widgets::msx_init sprite_locator

		for {set i 0} {$i < 32} {incr i} {
			osd create rectangle sprite_locator.box$i -relx -100 -rely -100 -relh 8 -relw 8 \
				-rgba 0xFF111140 -borderrgba 0xFF1111C0 -bordersize 1
			osd create text sprite_locator.box$i.snr -text $i -size 6 -y -6 -rgba 0xFFFFFFFF
			osd create text sprite_locator.box$i.pnr -text "" -size 6 -y  0 -rgba 0xFFFFFFFF
		}
		set sprite_locator_after_id [after frame [namespace code update_locator]]
		return "Sprite locator enabled, showing red rectangles around sprites..."
	}
}

proc update_locator {} {
	variable sprite_locator_enabled
	variable sprite_locator_after_id
	if {$sprite_locator_enabled} {
		osd_widgets::msx_update sprite_locator
		set mode_num [get_screen_mode_number]
		if {$mode_num == 0} return
		set r5 [vdpreg 5]
		set r11 [vdpreg 11]
		set special_y 216
		switch [get_screen_mode] {
			"1" -
			"2" -
			"3" {
				set base_addr [expr {$r5 * 0x80}]
				set special_y 208
			}
			"4" -
			"5" -
			"6" {
				set base_addr [expr {($r5 - 3) * 0x80}]
			}
			default {
				set base_addr [expr {($r5 + 256 * $r11) * 0x80}]
			}
		}
		# sprite size
		set size [expr {([vdpreg 1] & 2) == 2 ? 16 : 8}]
		# sprite magnification
		if {[expr {([vdpreg 1] & 1) == 1}]} {
			set size [expr {$size * 2}]
		}
		set next_are_hidden false
		for {set i 0} {$i < 32} {incr i} {
			if {$next_are_hidden} {
				set y -100
				set x -100
			} else {
				set y [vpeek [expr {$base_addr + 0 + 4*$i}]]
				if {$y == $special_y} {
					set next_are_hidden true
					set x -100
					set y -100
				} else {
					set x [vpeek [expr {$base_addr + 1 + 4*$i}]]
					incr y; # seems to be needed to make it look good... bug in osd_widgets::msx_init?
					set pnr [vpeek [expr {$base_addr + 2 + 4*$i}]]
					osd configure sprite_locator.box$i.pnr -text $pnr
				}
			}
			osd configure sprite_locator.box$i -relx $x -rely $y -relw $size -relh $size
		}
		set sprite_locator_after_id [after frame [namespace code update_locator]]
	}
}

namespace export toggle_sprite_locator

};# namespace sprite_locator

namespace import sprite_locator::*

The important bits are in in the update_locator proc of course. Please send in your fixes...

How to use: save somewhere, in the console use the source /path/to/script.tcl command to load it and then type toggle_sprite_locator to activate.

Again: please fix the addressing and stuff for me

thanks, i will check the correctness of addresses asap and let you know.
For now, i'm impressed on how konami "abused" those tricks to achieve gfx looking good

You can't set all four pattern numbers in 16x16 sprites. You just set the first one and the VDP gets the following three patterns, so you don't really need to show all four.

Perhaps those are leftovers from previous screens.